I need Windows 10 Product Key

[maia22]

I might have to change my hard drive soon.  I need to have my Product Key for Windows.  Can I ask HP for it?

[TheOldMan]

If you are anticipating the hard drive change, you can make a full system backup and therefore avoiding many obstacles in the future.

If you suspect a failing hard drive, that is the best approach.  If you are expecting something else, it is still an advantage to have a full system back saved to an external source.  There are many free alternatives or you can use a paid software.

BTW: the product key will not be needed for those methods.  Even if you are planning a new/fresh install of Windows 10, you do not need the Windows 10 product key - as soon as the new install has connected to the internet, it will activate with a digital key.

[NonSequitur777]

@maia22,

Welcome to our HP User Forum!

Perhaps I am misreading you, but I believe what you're asking is: how do I find out what my Windows product key is?

There are two easy ways to do this.

Method #1.) type cmd in your Windows search bar, right-click on the "Command Prompt" App, left-click on "Run as administrator", click: OK, and copy:

wmic path softwareLicensingService get OA3xOriginalProductKey

Right-click anywhere on the Administrator: Command Prompt screen, and the cmd instruction should automatically appear.

Hit enter.  You should see your Windows product Key: XXXXX-XXXXX-XXXXX-XXXXX-XXXXX.

Method #2:) Copy the following Script code (starting from "Option Explicit" to "End Function") and paste in Notepad, go to File and Save as (choose: "Rich Text Document") and save the document as: GetProductKey.vbs

You may get this message: "You are about to save the document in a Text-Only format, which will remove all formatting. Are you sure you want to do this?" to which you hit: Yes.

Option Explicit  
 
Dim objshell,path,DigitalID, Result  
Set objshell = CreateObject("WScript.Shell") 
'Set registry key path 
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\" 
'Registry key value 
DigitalID = objshell.RegRead(Path & "DigitalProductId") 
Dim ProductName,ProductID,ProductKey,ProductData 
'Get ProductName, ProductID, ProductKey 
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName") 
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID") 
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)  
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey 
'Show messbox if save to a file  
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then 
   Save ProductData  
End If 
 
 
 
'Convert binary to chars 
Function ConvertToKey(Key) 
    Const KeyOffset = 52 
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert 
    'Check if OS is Windows 8 
    isWin8 = (Key(66) \ 6) And 1 
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4) 
    i = 24 
    Maps = "BCDFGHJKMPQRTVWXY2346789" 
    Do 
           Current= 0 
        j = 14 
        Do 
           Current = Current* 256 
           Current = Key(j + KeyOffset) + Current 
           Key(j + KeyOffset) = (Current \ 24) 
           Current=Current Mod 24 
            j = j -1 
        Loop While j >= 0 
        i = i -1 
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput 
        Last = Current 
    Loop While i >= 0  
     
    If (isWin8 = 1) Then 
        keypart1 = Mid(KeyOutput, 2, Last) 
        insert = "N" 
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0) 
        If Last = 0 Then KeyOutput = insert & KeyOutput 
    End If     
     
 
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5) 
    
     
End Function 
'Save data to a file 
Function Save(Data) 
    Dim fso, fName, txt,objshell,UserName 
    Set objshell = CreateObject("wscript.shell") 
    'Get current user name  
    UserName = objshell.ExpandEnvironmentStrings("%UserName%")  
    'Create a text file on desktop  
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt" 
    Set fso = CreateObject("Scripting.FileSystemObject") 
    Set txt = fso.CreateTextFile(fName) 
    txt.Writeline Data 
    txt.Close 
End Function

You will see this file in your Documents (or wherever you saved it):

When you double-click on this file, you should see this:

Either save to file or write down this information so that you won't lose it.

Hope this was helpful.

Kind Regards,

NonSequitur777

[TheOldMan]

I assumed some things in my post as to why you might want to the Product key for Windows but there are third party software solutions besides the excellent method @NonSequitur777  posted.

Belarc Advisor   https://www.majorgeeks.com/files/details/belarc_advisor.html

Magical Jelly Bean Keyfinder   https://www.magicaljellybean.com/keyfinder/

ShowKeyPlus 1.1.15.0   https://www.techspot.com/downloads/7129-showkeyplus.html

ProduKey 1.97   https://www.techspot.com/downloads/7128-produkey.html#specs